case/4/0 Web Publishing: C:\Documents and Settings\hajsman\Dokumenty\Vyuka\Irs2\Projekt case40\Projekt03.csf - Vyhodnocovací funkce Check

[Celkový datový model] [Funkce] [Externí rohraní] [Stavové diagramy] [Datové elementy] [Entity] [Relace]
[Databáze] [Události] [Materiály] [Generovací funkce] [Vyhodnocovací funkce] [Konfigurace] [Uživatelé] [Projekt] [Home]

Vyhodnocovací funkce
Check_TypeFields
(Type Structure)

Vytvořeno:	12-11-1995 13:00:59
Poslední změna:	12-10-2002 13:49:35

Outputs a list of all type fields in the specified type structure with no data element or attribute assigned, or with no subtree.

Modul

Module: Type Structure

Zdrojový kód:

PROCEDURE Check_TypeFields FOR TYPESTRUCTURE
BEGIN
/*
  check type fields:
  - fields without refinement
  - fields without data element assignment
*/
  PRINT {"ARIAL",12,BOLD} "Test položek typové struktury ";
  PRINT {"ARIAL",12,BOLD,ITALIC} CONV$(Typestructure.Boxname),NL(2);

  first%=0;
  FOREACH Tfield WHERE Tfield.Typestructure=Typestructure.Name DO
    found%=0;
    FOREACH Relationpart WHERE Relationpart.Pfieldno=Tfield.Fieldno
                         AND Relationpart.Ppage=Tfield.Page
                         AND Relationpart.Typestructure=Tfield.Typestructure DO
      found%=1;
      BREAK;
    END
    FOREACH Tpart WHERE Tpart.Pfieldno=Tfield.Fieldno
                  AND Tpart.Ppage=Tfield.Page
                  AND Tpart.Typestructure=Tfield.Typestructure DO
      found%=1;
      BREAK;
    END
    FOREACH Tfield AS F WHERE F.Pfieldno=Tfield.Fieldno
                        AND F.Ppage=Tfield.Page
                        AND F.Typestructure=Tfield.Typestructure DO
      found%=1;
      BREAK;
    END
    FOREACH Tcond WHERE Tcond.Pfieldno=Tfield.Fieldno
                  AND Tcond.Ppage=Tfield.Page
                  AND Tcond.Typestructure=Tfield.Typestructure DO
      found%=1;
      BREAK;
    END

    IF found%=0 THEN
      isempty%=0;
      FOREACH Data WHERE Data.Name=Tfield.Data DO
        isempty%=1;
        BREAK;
      END
      FOREACH Relattribute WHERE Relattribute.Name=Tfield.Relattribute AND
                                 Relattribute.Relation=Tfield.Relation DO
        isempty%=1;
        BREAK;
      END
      IF isempty%=0 THEN
        IF first%=0 THEN
          PRINT {"ARIAL",10,BOLD} "Listové položky bez přiřazených datových elementů nebo atributů:",NL;
          first%=1;
        END
        PRINT {"ARIAL",10} TAB(4),CONV$(Tfield.Boxname),NL;
      END
    END

  END

  IF first%=0 THEN
    PRINT {"ARIAL",10} TAB(4),"Bez chyby.",NL;
  END

  PRINT NL(2);

END

Generováno: 16.10.2003 7:41	Systém: C:\Documents and Settings\hajsman\Dokumenty\Vyuka\Irs2\Projekt case40\Projekt03.csf	Generováno systémem case/4/0
Vygeneroval: Administrator	Soubor: C:\Documents and Settings\hajsman\Dokumenty\Vyuka\Irs2\Projekt case40\html\3792.htm	(C) microTOOL GmbH 2002